MediaVault releases

I just released MediaVault v1.4.1.

This version brings the following:
- Added an error message when podcast response is not a successful one
- Added scripts/start_player.sample script. This can be used to set the preferred player. This needs to be renamed as start_player to be used. The reason the file is named like that is to avoid replacements in future updates. The file includes configuration for different supported players, but more can be added.
- Added Trending Podcasts search based on category and/or language
- Added radio station bitrate and codec information in results list and at the right sidebar.
- Changed the about window to add more information.
- Fixed the error of not finding the texteditor.gadget on start

Find more info at https://ko-fi.com/post/MediaVault-1-4-1-released-W7W56J8CK

I would like to thank my supporters at https://ko-fi.com/walkero, who help me a lot on the further development of MediaVault.





You can download it at OS4Depot and from my Github at
https://github.com/walkero-gr/mediavault/releases/tag/v1.4.1

The project is open source and you can find the code at:
https://github.com/walkero-gr/mediavault

If you have any requests or you would like to report any problems you found, you can do it at:
https://github.com/walkero-gr/mediavault/issues

@walkero
Quote:
Wow, thanks for adding my request for bitrate and format so quickly!
Getting better and better. Nice to have a new program that fills a very useful function in the AmigaOS4 software collection!

Just a note. The update feature in the program worked great!

@walkero
Quote:
Might I suggest the following changes to the script so that users can change the player by just chaning one variable value instead of having to comment and uncommnet multiple lines.

I also added the "-showmode 1" option to ffplay to display an audio graph while playing. Seems more instresting to me.

;
; File: start_player
;
; Copyright (c) 2021, Georgios Sokianos
;
; This file is part of MediaVault
;
; Author: Georgios Sokianos (walkero@gmail.com)
; Date: October 2021
;
; Modified by Kevin Taddeucci (ktadd)
; made it easier to change players by setting a player variable.
; Added showmode 1 option to ffplay to display audio waves.
; Date: Oct. 10th, 2021
;
; Summary of File:
;
; This file contains code that is used to start
; user's preferred player. So, instead using a
; default player, MediaVault now executes this
; script, passing the URL of the source. User is
; able to change this script and make it work
; on his system as he wants.
; Remove semicolons at the start of the line of
; the player you would like to enable.
;
; This file is a sample and not used by
; MediaVault.
; You have to copy/rename it to: start_player
;

;========== Select Player ==========
; Choose the audio player by setting "player" to one of the following:
; 0 = AmigaAmp3
; 1 = ffplay
; 2 = emotion

SET player 0

;==============================

.KEY url/A
.BRA {
.KET }

If NOT "{url}" EQ ""

IF $player EQ "0"
If EXISTS APPDIR:AmigaAmp3
Run <>NIL: APPDIR:AmigaAmp3 "{url}"
EndIf
ENDIF

IF $player EQ "1"
If EXISTS APPDIR:ffplay
Set ffplayPID `Status COM=APPDIR:ffplay`
If VAL $ffplayPID GT 0
Break $ffplayPID
EndIf
Run <>NIL: APPDIR:ffplay -showmode 1 "{url}"
EndIf
ENDIF

IF $player EQ "2"
If EXISTS APPDIR:emotion
Set emotionPID `Status COM=APPDIR:emotion`
If VAL $emotionPID GT 0
Break $emotionPID
EndIf
Run <>NIL: APPDIR:emotion "{url}"
EndIf
ENDIF

IF $player GT "2"
Echo "invalid player value set"
ENDIF

Else
Echo "An argument is missing"
EndIf

@ktadd
Quote:

That's great. What I want to add there is a progress window, so that the user will know that something is happening. That would make it more complete, I believe.

Thank you so much for your feedback on the start_player script. Your work there is awesome.

To be honest, this script is a temporary solution, until I create the preferences window, because I wanted to provide a solution to anyone to use their player of choice, especially since AmigaAmp3 doesn't work so well with a lot of podcast sources. So, I was thinking, what can I do in 5 days to solve that issue? And I believe that this is a good solution.

What I expect is that users are going to delete most of the lines and keep only the ones for their player of choice. Or even change one of them to cover their needs. So I wouldn't like to make it more complicated, so that they feel is difficult or afraid to make changes. I want to keep it simple. We will see based on the feedback I will get.

When preferences will come, user will be able to set a global player from there, or even start a specific script if he/she wants. But I will also have options to set the video player for video playback, or different players based on the section (radio, podcast, dlna servers).

Thank you again for testing MediaVault and find it so useful. To be honest, I wanted such an application so much, and gave me so much pleasure during the development of it.

Along with your awesome applications, and others' work we can make AmigaOS 4 even more useful for every day usage.

@walkero
Quote:
Yes, this is the feature that I want and why I modified the script to make it easy to change. I want to use AmigaAmp3 for Radio and ffplay for Podcasts.

I understand you don't want to put energy into the script because you are planning to replace it but, if you would pass the play mode to the script I'd be happy to modify it to allow the user to set two variables at the top to set the player for each mode.

I understand if you would rather not do that now.
Maybe see if that's an important feature to users.

@ktadd
Why don't you add a RequestChoice at the script. This way, the script will ask you which player to use, with a nice requester. Maybe that's a good solution, right?

@walkero
Quote:
Could be a solution for now. It would mean that the user would be nagged by a requester each time they play a new stream. I might add it and include a variable the user could set to disable the requester and use the player variable as it is now. That way, anyone who wanted to always use the same player for everything won't be nagged with a requester.

If others have any feedback on this, please post. Knowing what other users would like is always a motivater.

@ktadd

Getting a requester each time you pick a new stream could help.
I click on a stream and select AmiAmp.
If that fails, I click on the same stream and select ffplay.

Even better if this only occurs on the podcast selections as that's where the problem occurs.

Cheers

@TiredOfLife
Quote:
I've modified the script to display a requester which will default to AmigaAmp if a selection isn't made in 3 seconds. The requester can be dissabled completely by modifying a variable.

Quote:
There is no way in the script to tell if the selection is a podcast or not, unless I try to parse URL's and try to determice by the extension. Not worth it to go through that much trouble though given the script is a temporary solution.

@ktadd

Quote:

Good idea, that will very useful.

Quote:

Did think I was pushing it with that though but not a dev so just thought i'd suggest it in case it was easier than I thought it would be.
Your new modified script negates the need for it in any case.

Cheers

Quote:

Not needed at all. I can easily pass an extra argument from MediaVault about the type of the audio (podcast, radio station).

@ktadd
Would you like to finalize your script, and add a second argument for the type, and send it to me? I will make a new MediaVault release with those changes after AmiWest, along with some more changes I am working on right now.

@walkero
Quote:
Ok. Do you mind if I post the current (V1.2) version of the script here and on Amigaworld so people can use it now?

@ktadd
I don't mind at all. That's why I made this script, so it is able to be changed by everyone.

@All

Here is a MediaVault script that has been modified with the following changes:

* Made it easier to change players by setting a player variable.
* Added showmode 1 option to ffplay to display audio waves.
* Added ability to show requester to choose player when play is clicked.
* Requester can be disabled by setting a variable in script.
* Changed error messages so they display in a requester.

See the "User Settings" area in the script to set variables to make
it work the way you want it to. Directions in script.

Copy the code below and past it into an editor. Then save it to the
"MediaVault/scripts" folder with the name, "start_player". It will then be
executed when you click "Play" in MediaVault.


;
; File: start_player
;
; Version 1.2
;
; Copyright (c) 2021, Georgios Sokianos
;
; This file is part of MediaVault
;
; Author: Georgios Sokianos (walkero@gmail.com)
; Date: October 2021
;
; Modified by Kevin Taddeucci (ktadd)
; Date: Oct. 10th, 2021
; Made it easier to change players by setting a player variable.
; Added showmode 1 option to ffplay to display audio waves.
;
; Date: Oct. 11th, 2021
; Added ability to show requester to choose player.
; Changed error messages so they display in a requester.
;
; Summary of File:
;
; This file contains code that is used to start
; user's preferred player. So, instead using a
; default player, MediaVault now executes this
; script, passing the URL of the source. User is
; able to change this script and make it work
; on his system as he wants.
; Set the variables in the "User Settings" area below.
;
; This file is a sample and not used by
; MediaVault.
; You have to copy/rename it to: start_player
; Place this script in the MediaVault/scripts directory.

.KEY url/A
.BRA {
.KET }

;================ User Settings ================
;
; Choose the audio player by setting "player" to one of the following:
; 0 = Emotion
; 1 = AmigaAmp3
; 2 = ffplay

SET player 1


; Choose to show a requester to select player when 'Play' is clicked.
; 0 = Do not show requester.
; 1 = Show requester

SET show_req 1

; (Note: player setting above will be overriden if requester is used.)

;========== Edit below this line at your own risk ==========

If NOT "{url}" EQ ""

if $show_req EQ "1"

SET player `RequestChoice "MediaVault Player Select" "Select program to play stream...*N*NTo disable requester:*NSet 'show_req' in 'Start_Player' script to 0.*N*N(Requester will auto close in 3 seconds!)" "AmigaAmp3" "ffplay" "Emotion" TYPE QUESTION TIMEOUTSECS 3`

;if requester timed out, set to AmigaAmp3
if $player EQ "-1"
Set player 1
Endif

Endif

If $player EQ "0"
If EXISTS APPDIR:emotion
Set emotionPID `Status COM=APPDIR:emotion`
If VAL $emotionPID GT 0
Break $emotionPID
EndIf
Run <>NIL: APPDIR:emotion "{url}"
EndIf
Endif

IF $player EQ "1"
If EXISTS APPDIR:AmigaAmp3
Run <>NIL: APPDIR:AmigaAmp3 "{url}"
EndIf
ENDIF

If $player EQ "2"
If EXISTS APPDIR:ffplay
Set ffplayPID `Status COM=APPDIR:ffplay`
If VAL $ffplayPID GT 0
Break $ffplayPID
EndIf
Run <>NIL: APPDIR:ffplay -showmode 1 "{url}"
EndIf
Endif

If $player GT "2"
RequestChoice "MediaVault Player" "Error in 'start_player' script!*N*NInvalid player selected!" "OK" TYPE ERROR
Endif

Else
RequestChoice "MediaVault Player" "Error in 'start_player' script!*N*NNo URL detected!" "OK" TYPE ERROR
EndIf

@ktadd

Nothing happens when I use this script.
Tried creating one from scratch and also copying and pasting this over the script created by Walkero.

Either way when pressing the play button, nothing happens.
The original script from Walkero works fine, I can get streams to play in Emotion no problem.

Cheers

@TiredOfLife
Quote:
Unfortunatly it looks like the code posting doesn't like single quotes and puts some invisable color change characters in the text.

I've taken the code out of the code tags so if you go back to the code post and follow the directions it will work now.

Sorry about that.

@ktadd

That's got it, working great now.

Thanks very much.

Cheers

@ktadd

Thank you so much for this awesome script. I will add it in the next release.

Quote:

Just a small correction. The file should be named "start_player", without the quotes.

@walkero
Quote:
Fixed Thanks!

Great program, I love it. Did not have a chance to test it before today, but after I did, my whole family jumped around Amiga and starts dancing and singing while listening to Serbian music. Good times! There were couple of crashes and I think this is related to the Serbian latin characters reflecting as "?" in the radio station name. Not sure about it yet (didn't pay attention), will test it further and let you know. Also "Amiga Ireland" podcast is not working at all. Does it work for you, in AmiAMP? Thanks again!

https://u.pcloud.link/publink/show?cod ... w77GBObL44A5kQuLV5JYrJ1Xk